오늘 날짜를 입력학면 오늘이 올해의 몇 번째 날인지

엑셀 월 주차 구하기 함수 공식

엑셀 월 주차 구하기 함수 목차 바로가기

1. 엑셀 상황별 주 단위 계산 공식 사용법 - 영상강의
2. 사용된 공식 요약
3. 예제파일 다운로드
4. 엑셀 월 주차 계산 함수 공식 설명
5. 공식의 동작원리

함수 공식

공식1) 월 주차 계산 (기본)
- 매월 1일 기준으로 주 번호를 계산합니다. 간단한 공식이지만, 전월과 당월이 서로 분리되어 한 주 안에 온전하게 7일이 포함되지 않는 문제가 발생합니다.

=WEEKNUM(날짜,기준)-WEEKNUM(EOMONTH(날짜,-1)+1,기준)+1

공식2) 특정 요일 기준 월 주차 계산
- 매월 첫번째로 시작되는 특정요일을 기준으로 주 번호를 계산합니다. 당월 첫번째 날이 전월의 마지막주로 포함되며, 매 주마다 온전한 7일로 구성됩니다.

=WEEKNUM(DATE(YEAR(날짜),1,DAY(날짜-WEEKDAY(날짜,기준)+1)),WEEKDAY(DATE(YEAR(날짜),1,1),11)+10)

공식3) 매월 1일 기준 월 주차 계산
- 매월 1일을 기준으로 주 번호를 계산합니다. 전월 마지막 날이 당월의 첫번째 주로 포함되며, 매 주마다 온전한 7일로 구성됩니다.

=IF(OR(WEEKNUM(DATE(YEAR(날짜),MONTH(날짜),DAY(날짜-WEEKDAY(날짜,기준)+1))+7)<WEEKNUM(DATE(YEAR(날짜),MONTH(날짜),DAY(날짜-WEEKDAY(날짜,기준)+1))),WEEKNUM(날짜,기준)=WEEKNUM(EOMONTH(날짜,0)+1,기준)),1,WEEKNUM(날짜,기준)-WEEKNUM(EOMONTH(날짜,-1)+1,기준)+1)

각 공식에 대한 자세한 사용방법은 아래 영상강의에서 상세히 설명해드렸습니다.

인수 설명

예제파일 다운로드

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

호환성

사용된 기초 함수

엑셀 월 주차 구하기 함수 공식 알아보기

공식 설명

특정 날짜의 월 주차를 구하는 함수 공식입니다. WEEKNUM 함수의 두번째 인수를 변경하여 계산 방식에 따라 일요일시작 또는 월요일시작 등으로 자유롭게 계산 가능합니다.

보다 쉬운 이해를 위해 2020년 3월 9일을 예제로 알아보겠습니다.

일요일 시작으로 월 주차를 구할 경우

=WEEKNUM("2020-03-09",17)-WEEKNUM(EOMONTH("2020-03-09",-1)+1,17)+1
=2  '일요일 시작이므로 둘째주로 계산됩니다.

월요일 시작으로 월 주차를 구할 경우

=WEEKNUM("2020-03-09",11)-WEEKNUM(EOMONTH("2020-03-09",-1)+1,11)+1
=3  '월요일 시작이므로 셋째주로 계산됩니다.

하지만 이렇게 월 주차를 계산할 경우, 전달의 마지막날과 이번달 첫째날이 서로 분리되어 주차가 계산됩니다. 따라서, 한 주안에 온전히 7일이 들어가지 않는 문제가 발생하게 되는데요.

이러한 문제를 해결하기 위하여 2가지 대안책을 고려할 수 있으며, 각 방법에 따른 월 주차 계산 결과는 아래와 같습니다.

특정 요일을 기준으로 월 주차를 구할 경우

특정 요일을 기준으로 월 주차를 구할 경우, 매월 특정 요일이 처음으로 시작되는 주를 당월의 첫번째 주로 계산합니다. 따라서 당월의 첫째날이 이전 달의 마지막주로 포함되어 계산됩니다.

매월 1일 기준으로 월 주차를 구할 경우

매월 1일을 기준으로 월 주차를 구하게 되면, 매월 1일이 포함된 전체 주를 당월의 첫째주로 계산합니다. 따라서 이전 달의 마지막날이 당월의 첫째주로 포함되어 계산됩니다.

각 상황별로 월 주차 계산 공식을 적용하는 방법에 대한 상세한 설명은 아래 엑셀 날짜 주 단위 계산 공식 사용법 영상강의를 참고해주세요.

공식의 동작원리

1. 월 주차 계산 기본 공식

1. EOMONTH 함수로 전달 마지막 날을 계산합니다.

   =EOMONTH("2020-03-09",-1)
   ="2020-02-29"  '전달 마지막날이 계산됩니다.

2. EOMONTH 함수로 계산된 날짜에 1을 더하면 이번달 1일이 계산됩니다.

   =EOMONTH("2020-03-09"-1)+1
   ="2020-02-09"+1
   ="2020-03-01"

3. WEEKNUM 함수로 오늘 날짜의 주차를 계산합니다. WEEKNUM 함수는 '전체 년도'의 주차를 계산합니다.

   =WEEKNUM("2020-03-09",1)
   =11  '3월 9일은 2020년도의 11번째 주차 입니다.

4. WEEKNUM 함수로 이번달 1일의 주차를 계산합니다.

   =WEEKNUM(EOMONTH("2020-03-09",-1)+1,1)
   =WEEKNUM("2020-03-01")
   =10  '3월 1일은 2020년도의 10번째 주차입니다.

5. 오늘 날짜의 주차 - 이번달 첫째날 주차 + 1 로 월 주차 계산을 마무리합니다.

   =11-10+1
   =2  '3월 9일은 3월달의 두번째 주차 입니다.

2. 특정 요일 기준 월 주차 계산 공식

1. WEEKDAY 함수를 사용하여 날짜가 포함된 주의 시작요일을 계산합니다.

   '날짜: 2020-01-16, 기준 : 월요일
   =날짜-WEEKDAY(날짜,기준)+1
   ='2020-01-16'-WEEKDAY('2020-01-16',11)+1
   ='2020-01-16'-4+1
   ='2020-01-16'-3
   ='2020-01-13' '20년 1월 16일이 포함된 주의 월요일은 1월 13일 입니다.

2. DAY 함수로 해당 시작요일의 '일'을 반환합니다.

   =DAY(날짜-WEEKDAY(날짜,기준)+1)
   =DAY('2020-01-16'-WEEKDAY('2020-01-16',11)+1)
   =DAY('2020-01-13')
   =13

3. WEEKDAY 함수로 같은 해 1월 1일의 요일번호를 계산합니다.

   =WEEKDAY(DATE(YEAR(날짜),1,1),11)+10
   =WEEKDAY(DATE(YEAR('2020-01-16'),1,1),11)+10
   =WEEKDAY(DATE(2020,1,1),11)+10
   =3+10
   =13  '20년 1월 1일은 수요일이므로 13이 반환됩니다.

4. 자 이제, 우리는 특정 요일 기준으로 주차를 계산하기 위해 '날짜'가 몇월이든 상관없이 매년 '1월'을 기준으로 주차를 계산할 수 있는데요.
   계산 원리를 단계별로 알아보겠습니다.
5. 우리는 올해 1월 1일이 무슨 요일에 시작하는지 알고 있습니다. 따라서 1월달의 주차는 아래와 같이 계산됩니다.
   
   1월 1일을 기점으로 1월의 월 주차를 계산하면 위와 같습니다.
6. 그리고 우리가 지정한 특정 요일은 매월 1일~7일 사이에 발생할 것입니다.
   예를들어 2월 달을 보겠습니다. 2월달의 첫번째 월요일은 3일에 시작했습니다. 그리고 그 다음주는요? 10일, 17일, 24일.. 순으로 증가하게 됩니다. 이제 감이 오시죠?
   
   2월달의 첫번째 월요일은 3일날 시작하여, 10, 17, 24로 증가합니다.
7. 따라서 1월달을 기준으로 보면, 1월달의 첫째주는 1/1~1/7, 둘째주는 1/8~1/15,.. 순으로 증가하게 되어 1월달을 기준으로 계산을 하지만 해당 월의 특정요일을 기준으로 한 주차가 계산됩니다.
   
   이를 1/1을 기점으로 한 주차에 대입하면, 특정요일을 기준으로 한 월 주차가 계산됩니다.

관련링크 : MS 홈페이지 엑셀 WEEKNUM 함수 사용법