윈도우에서 system e 드라이브가 왜 생기하뇨

Question

주요 콘텐츠로 건너뛰기

이 브라우저는 더 이상 지원되지 않습니다.

목차 Show

이 문서의 내용
구성 파일 만들기
파티션 초기화 스크립트
푸시 단추 초기화 구성 파일(ResetConfig.xml)
1단계: 대상 컴퓨터에 구성 파일 추가
2단계: Windows에서 복구 미디어를 만들 수 있는지 테스트
3단계: 복구 미디어 테스트
문제 해결
시스템 드라이브 식별
여러 로컬 드라이브가 검색되면 Windows는 다음 순서로 검색하여 시스템 드라이브를 식별합니다.

최신 기능, 보안 업데이트, 기술 지원을 이용하려면 Microsoft Edge로 업그레이드하세요.

아티클
11/16/2022
읽는 데 11분 걸림

이 문서의 내용

복구 미디어(완전 메탈 복구)는 사용자가 하드 드라이브를 교체하거나 드라이브를 완전히 지워야 하는 경우에도 Windows 디바이스를 초기화 상태로 복원하는 데 도움이 됩니다.

Windows는 최근 Windows 및 드라이버 업데이트를 비롯한 기본 제공 Windows 파일과 OEM 프로비전 패키지에 포함된 사용자 지정을 사용하여 복구 미디어를 만듭니다.

기본 파티션 레이아웃을 사용하여 Windows를 배포하는 경우 사용자는 기본적으로 완전 메탈 복구 미디어를 만들 수 있습니다.

사용자 지정 파티션 레이아웃을 사용하여 Windows를 배포하는 경우 사용자가 완전 메탈 복구 미디어를 만들 수 있도록 몇 가지 구성 파일을 추가해야 합니다.

사용자 지정 파티션 레이아웃을 다시 설정하는 수정된 DiskPart 스크립트인 파티션 초기화 스크립트
Windows 및 Windows RE 파티션을 식별하는 푸시 단추 초기화 구성 파일(ResetConfig XML)

참고

Windows 10 버전 1607 이상에서는 사일로 프로비전 패키지에 캡처된 데스크톱 애플리케이션 및 설정이 이 미디어를 사용하여 복원되지 않습니다. ScanState 도구를 사용하여 캡처된 일반 사용자 지정 패키지(.ppkg)는 이 문제의 영향을 받지 않습니다.

구성 파일 만들기

파티션 초기화 스크립트

메모장에서 하드 드라이브를 초기화한 후 하드 드라이브를 분할하는 구성 파일을 만듭니다. 이 스크립트는 다음 예외를 제외하고 하드 드라이브에 파티션을 만드는 데 사용되는 스크립트와 동일해야 합니다.
- 스크립트에는 드라이브를 선택하거나 정리하는 명령이 포함되어서는 안 됩니다. Windows는 시스템 드라이브를 자동으로 식별합니다. 자세한 내용은 이 항목의 뒷부분에 있는 시스템 드라이브 식별을 참조하세요.
- 스크립트는 시스템 파티션, Windows 파티션 및 Windows RE 도구 파티션에 문자를 할당해야 합니다.

참고

사용자 지정 파티션 레이아웃을 사용하는 경우 Windows RE 도구 파티션의 크기는 나중에 더 큰 크기를 허용하기에 충분한 여유 공간이 있어야 합니다. Windows RE 도구 파티션의 권장 크기는 990MB이며, 사용 가능한 최소 크기는 250MB입니다.

예:

UEFI(UEFI/GPT 기반 하드 드라이브 파티션 기반):

rem == ResetPartitions-UEFI.txt ==
rem == These commands are used with DiskPart to
rem    reset the drive and recreate five partitions
rem    for a UEFI/GPT-based computer.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==
rem == The differences between this file and
rem    CreatePartitions-UEFI.txt
rem    are noted in parenthesis.
rem       (NOT USED: select disk 0)
rem       (NOT USED: clean)
convert gpt
rem == 1. System partition =========================
create partition efi size=100
rem    ** NOTE: For Advanced Format 4Kn drives,
rem               change this value to size = 260 **
format quick fs=fat32 label="System"
assign letter="S"
rem == 2. Microsoft Reserved (MSR) partition =======
create partition msr size=128
rem == 3. Windows partition ========================
rem ==    a. Create the Windows partition ==========
create partition primary
rem ==    b. Create space for the recovery tools ===
shrink minimum=500
rem       ** Update this size to match the size of
rem          the recovery tools (winre.wim)
rem          plus some free space.
rem
rem ==    c. Prepare the Windows partition =========
format quick fs=ntfs label="Windows"
assign letter="C"
rem === 4. Recovery tools partition ================
create partition primary
format quick fs=ntfs label="Recovery tools"
assign letter="R"
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
list volume

BIOS(BIOS/MBR 기반 하드 드라이브 파티션 기반):

rem == ResetPartitions-BIOS.txt ==
rem == These commands are used with DiskPart to
rem    reset the drive and create three partitions
rem    for a BIOS/MBR-based computer.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==
rem == The differences between this file and
rem    CreatePartitions-BIOS.txt
rem    are noted in parenthesis.
rem       (NOT USED: select disk 0 )
rem       (NOT USED: clean )
rem == 1. System partition ======================
create partition primary size=100
format quick fs=ntfs label="System"
assign letter="S"
active
rem == 2. Windows partition =====================
rem ==    a. Create the Windows partition =======
create partition primary
rem ==    b. Create space for the recovery tools  
shrink minimum=500
rem       ** Update this size to match the size of
rem          the recovery tools (winre.wim)
rem          plus some free space.
rem ==    c. Prepare the Windows partition ======
format quick fs=ntfs label="Windows"
assign letter="C"
rem == 3. Recovery tools partition ==============
create partition primary
format quick fs=ntfs label="Recovery"
assign letter="R"
set id=27
list volume

파일(예: E:\Recovery\RecoveryImage\ResetPartitions-UEFI.txt)을 저장합니다.

푸시 단추 초기화 구성 파일(ResetConfig.xml)

메모장에서 푸시 단추 초기화 파티션 스크립트를 가리키는 구성 파일을 만듭니다.
이 파일을 구성하는 방법에 대한 자세한 내용은 ResetConfig XML 참조를 참조하세요.

UEFI:

    <?xml version="1.0" encoding="utf-8"?>
    <!-- ResetConfig.xml for UEFI -->
    <Reset>
        <!-- May be combined with custom scripts – insert Run Phase elements here -->
        <SystemDisk>
            <DiskpartScriptPath>ResetPartitions-UEFI.txt</DiskpartScriptPath>
            <MinSize>75000</MinSize>
            <WindowsREPartition>4</WindowsREPartition>
            <WindowsREPath>Recovery\WindowsRE</WindowsREPath>
            <OSPartition>3</OSPartition>
        </SystemDisk>
    </Reset>

BIOS:

    <?xml version="1.0" encoding="utf-8"?>
    <!-- ResetConfig.xml for BIOS -->
    <Reset>
        <!-- May be combined with custom scripts – insert Run Phase elements here -->
        <SystemDisk>
            <DiskpartScriptPath>ResetPartitions-BIOS.txt</DiskpartScriptPath>
            <MinSize>75000</MinSize>
            <WindowsREPartition>3</WindowsREPartition>
            <WindowsREPath>Recovery\WindowsRE</WindowsREPath>
            <OSPartition>2</OSPartition>
        </SystemDisk>
    </Reset>

UTF-8 파일 형식을 사용하여 파일을 저장합니다.
파일을 클릭한 후 다른 이름으로 저장을 클릭합니다. 인코딩 상자에서 UTF-8을 선택하고 이 파일을 E:\Recovery\RecoveryImage\ResetConfig.xml에 저장합니다.

사용자는 필요할 때 이 옵션을 사용하여 복구 미디어를 만들 수 있습니다.

1단계: 대상 컴퓨터에 구성 파일 추가

대상 컴퓨터에서 구성 파일과 함께 USB 플래시 드라이브를 삽입합니다.
구성 파일을 대상 컴퓨터에 복사합니다.

    Copy E:\Recovery\RecoveryImage\* R:\RecoveryImage\*

여기서 E는 USB 플래시 드라이브의 드라이브 문자이고 R은 복구 이미지 파티션의 드라이브 문자입니다.

2단계: Windows에서 복구 미디어를 만들 수 있는지 테스트

대상 컴퓨터를 다시 시작하고 OOBE(첫 실행 경험)를 완료합니다.
시작을 클릭하고, 복구 드라이브 만들기를 입력한 후 복구 드라이브 만들기를 선택하고, UAC 프롬프트에서 예를 클릭합니다.
USB 플래시 드라이브를 삽입합니다.
PC에서 복구 드라이브로 복구 파티션 복사>다음>다음>만들기를 선택합니다.

3단계: 복구 미디어 테스트

운영 체제가 없는 컴퓨터에서 복구 미디어를 삽입합니다.
컴퓨터를 시작하고 키를 눌러 펌웨어 부팅 메뉴를 연 다음, 적절한 부팅 디바이스를 선택합니다.
Windows RE 도구 메뉴에서 키보드 레이아웃(예: 미국)을 선택합니다.
다음 항목모두 제거>를> 클릭합니다. 드라이브를 정리하라는 메시지가 표시되면 예를 선택합니다.
예, 드라이브 다시 분할>내 파일만 제거>초기화를 선택합니다.

문제 해결

ResetConfig.xml이 UTF-8 파일로 저장되어 있는지 확인합니다.
ResetConfig.xml 파일의 <DiskpartScriptPath> 요소에 나열된 파일 이름이 Diskpart 스크립트의 파일 이름과 일치하는지 확인합니다.
Diskpart 스크립트에 드라이브를 선택하거나 드라이브(select disk 0, clean)를 정리하는 명령이 포함되어 있지 않은지 확인합니다.

시스템 드라이브 식별

Windows는 다음 방법을 사용하여 시스템 드라이브를 식별합니다.

BIOS 기반 컴퓨터: BIOS에서 보고한 시스템 드라이브가 사용됩니다.

UEFI 기반 컴퓨터: reagentc /setreimage 명령을 사용하여 Windows RE를 사용하도록 설정되면 Windows는 시스템 디스크의 어댑터 위치 경로와 GUID를 UEFI 변수에 씁니다. 이 단계는 시스템 및 OS 파티션이 모두 시스템 드라이브에 있을 때만 수행됩니다. 변수는 필요한 경우 Windows RE가 비활성화된 다음, 다시 활성화되면 업데이트됩니다.